mirror of
https://github.com/pbatard/rufus.git
synced 2024-08-14 23:57:05 +00:00
f4ed6e4650
* DOS creation was broken due to missing unlock + close * added label validation to prevent errors * added ellipsis to status bar * also bumped version to rufus next and fixed f/non-f
86 lines
2.8 KiB
Text
86 lines
2.8 KiB
Text
AC_INIT([rufus], [1.1.1], [https://github.com/pbatard/rufus/issues], [rufus], [http://rufus.akeo.ie])
|
|
AM_INIT_AUTOMAKE([-Wno-portability foreign no-dist no-dependencies])
|
|
AC_CONFIG_SRCDIR([src/rufus.c])
|
|
AC_CONFIG_MACRO_DIR([m4])
|
|
# Enable silent build rules by default (Automake v1.11 or later).
|
|
# Disable by either passing --disable-silent-rules to configure or passing V=1 to make
|
|
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
|
|
[AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
|
|
|
|
AC_PREREQ([2.50])
|
|
AC_PROG_CC
|
|
AC_PROG_RANLIB
|
|
AC_PATH_PROG(RM, rm, rm)
|
|
AC_CHECK_TOOL(STRIP, strip, strip)
|
|
AC_CHECK_TOOL(WINDRES, windres, windres)
|
|
AC_C_INLINE
|
|
AC_DEFINE([_GNU_SOURCE], [], [Use GNU extensions])
|
|
|
|
# Clang needs an explicit WIN32_WINNT defined else it produces warnings
|
|
# in msapi_utf8.h - including winver.h only doesn't work
|
|
AM_CFLAGS="${AM_CFLAGS} -DWINVER=0x501 -D_WIN32_IE=0x501 -D_WIN32_WINNT=0x501"
|
|
AM_LDFLAGS="${AM_LDFLAGS} -Wl,-no-undefined"
|
|
|
|
AC_ARG_WITH([freedos],
|
|
[AS_HELP_STRING([--with-freedos],
|
|
[embed FreeDOS support (default=yes)])],
|
|
[],
|
|
[with_freedos=yes])
|
|
if test "x$with_freedos" != "xno" ; then
|
|
AM_RCFLAGS="${AM_RCFLAGS} -DWITH_FREEDOS"
|
|
EXESUFFIX="f"
|
|
fi
|
|
|
|
AC_ARG_WITH([syslinux],
|
|
[AS_HELP_STRING([--with-syslinux],
|
|
[embed Syslinux support (default=yes)])],
|
|
[],
|
|
[with_freedos=yes])
|
|
if test "x$with_syslinux" != "xno" ; then
|
|
AM_RCFLAGS="${AM_RCFLAGS} -DWITH_SYSLINUX"
|
|
fi
|
|
|
|
# Debug symbols
|
|
AC_ARG_ENABLE([debug],
|
|
[AS_HELP_STRING([--enable-debug],
|
|
[keep debug symbols for gdb (default=yes)])],
|
|
[debug_enabled=$enableval],
|
|
[debug_enabled='yes'])
|
|
if test "x$debug_enabled" != "xno" ; then
|
|
CFLAGS="-g -O2"
|
|
else
|
|
CFLAGS="-O2"
|
|
LDFLAGS="-s"
|
|
fi
|
|
|
|
AC_MSG_RESULT([enabling Large File Support (ISO support)])
|
|
AM_CFLAGS="$AM_CFLAGS -D_FILE_OFFSET_BITS=64 -D_OFF_T_DEFINED -D_OFF_T_ -D_off_t=off64_t -Doff_t=off64_t"
|
|
|
|
# check for -Wno-pointer-sign compiler support (GCC >= 4)
|
|
saved_CFLAGS="${CFLAGS}"
|
|
CFLAGS="$CFLAGS -Wno-pointer-sign"
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
|
|
[nopointersign_cflags="-Wno-pointer-sign"], [nopointersign_cflags=""])
|
|
CFLAGS="${saved_CFLAGS}"
|
|
|
|
AM_CFLAGS="$AM_CFLAGS -std=gnu99 -Wshadow -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags"
|
|
|
|
AC_SUBST([VISIBILITY_CFLAGS])
|
|
AC_SUBST([AM_CFLAGS])
|
|
AC_SUBST([AM_LDFLAGS])
|
|
AC_SUBST([AM_RCFLAGS])
|
|
AC_SUBST([EXESUFFIX])
|
|
|
|
AC_CONFIG_FILES([Makefile])
|
|
AC_CONFIG_FILES([src/Makefile])
|
|
AC_CONFIG_FILES([src/ms-sys/Makefile])
|
|
AC_CONFIG_FILES([src/syslinux/libfat/Makefile])
|
|
AC_CONFIG_FILES([src/syslinux/libinstaller/Makefile])
|
|
AC_CONFIG_FILES([src/libcdio/iso9660/Makefile])
|
|
AC_CONFIG_FILES([src/libcdio/udf/Makefile])
|
|
AC_CONFIG_FILES([src/libcdio/driver/Makefile])
|
|
AC_OUTPUT
|
|
|
|
AC_MSG_NOTICE([
|
|
FreeDOS Support : $(test "x$with_freedos" != "xno" && echo enabled || echo disabled)
|
|
Syslinux Support : $(test "x$with_syslinux" != "xno" && echo enabled || echo disabled)])
|