vig/src/ast.zig

const std = @import("std");
const tokens = @import("tokens.zig");
const Token = tokens.Token;

pub const NodeList = std.ArrayList(*Node);
pub const StmtList = std.ArrayList(*Stmt);
pub const ExprList = std.ArrayList(*Expr);
pub const ParamList = std.ArrayList(ParamDecl);
pub const ConstList = std.ArrayList(SingleConst);

// TODO convert FnCall to something like PrefixOp / InfixOp / SuffixOp
pub const NodeType = enum {
    Root,
    FnDecl,
    ConstDecl,
    Block,
    Expr,
    Stmt,
};

pub const ParamDecl = struct {
    name: Token,
    typ: Token,
};

pub const FnDecl = struct {
    func_name: Token,
    params: ParamList,
    return_type: Token,
    body: StmtList,
};

pub const SingleConst = struct {
    name: Token,
    expr: *Expr,
};

pub const BinaryExpr = struct {
    left: *Expr,
    op: Token,
    right: *Expr,
};

pub const UnaryExpr = struct {
    op: Token,
    right: *Expr,
};

// looks like a BinaryExpr, but is not a BinaryExpr
pub const LogicalExpr = struct {
    left: *Expr,
    op: Token,
    right: *Expr,
};

pub const LiteralExpr = union(enum) {
    Bool: bool,
    Integer: []const u8,
    Float: []const u8,
    String: []const u8,
};

pub const AssignExpr = struct {
    name: Token,
    value: *Expr,
};

pub const ExprType = enum {
    Assign,

    // vardecls as expressions is a hack
    VarDecl,

    Binary,
    Unary,
    Logical,
    Literal,
    Variable,
    Call,
    Grouping,
};

pub const VarDecl = struct {
    assign: AssignExpr,
    mutable: bool = false,
};

pub const CallExpr = struct {
    callee: *Expr,
    paren: Token,
    arguments: ExprList,
};

pub const Expr = union(ExprType) {
    Assign: AssignExpr,
    VarDecl: VarDecl,

    Binary: BinaryExpr,
    Unary: UnaryExpr,
    Logical: LogicalExpr,
    Literal: LiteralExpr,

    Variable: Token,
    Grouping: *Expr,
    Call: CallExpr,
};

pub const Block = std.ArrayList(*Stmt);

pub const IfStmt = struct {
    condition: *Expr,
    then_branch: Block,
    else_branch: ?Block,
};

pub const LoopStmt = struct {
    condition: ?*Expr,
    then_branch: Block,
};

pub const Stmt = union(enum) {
    Expr: *Expr,
    Println: *Expr,

    If: IfStmt,
    Loop: LoopStmt,

    Return: ReturnStmt,

    pub const ReturnStmt = struct {
        keyword: Token,
        value: *Expr,
    };

    pub fn mkPrintln(allocator: *std.mem.Allocator, expr: *Expr) !*Stmt {
        var stmt = try allocator.create(Stmt);
        stmt.* = Stmt{ .Println = expr };
        return stmt;
    }

    pub fn mkIfStmt(
        allocator: *std.mem.Allocator,
        condition: *Expr,
        then: Block,
        else_branch: ?Block,
    ) !*Stmt {
        var stmt = try allocator.create(Stmt);
        stmt.* = Stmt{
            .If = IfStmt{
                .condition = condition,
                .then_branch = then,
                .else_branch = else_branch,
            },
        };

        return stmt;
    }

    pub fn mkLoop(
        allocator: *std.mem.Allocator,
        condition: ?*Expr,
        then: Block,
    ) !*Stmt {
        var stmt = try allocator.create(Stmt);
        stmt.* = Stmt{
            .Loop = LoopStmt{
                .condition = condition,
                .then_branch = then,
            },
        };

        return stmt;
    }

    pub fn mkReturn(allocator: *std.mem.Allocator, tok: Token, value: *Expr) !*Stmt {
        var stmt = try allocator.create(Stmt);
        stmt.* = Stmt{
            .Return = ReturnStmt{
                .keyword = tok,
                .value = value,
            },
        };

        return stmt;
    }
};

pub const Node = union(NodeType) {
    Root: NodeList,
    FnDecl: FnDecl,
    ConstDecl: ConstList,

    Block: StmtList,

    Expr: *Expr,
    Stmt: *Stmt,
};

pub fn mkRoot(allocator: *std.mem.Allocator) !*Node {
    var node = try allocator.create(Node);
    node.* = Node{ .Root = NodeList.init(allocator) };
    return node;
}

fn printIdent(ident: usize) void {
    var i: usize = 0;
    while (i < ident) : (i += 1) {
        std.debug.warn("\t");
    }
}

fn print(ident: usize, comptime fmt: []const u8, args: ...) void {
    printIdent(ident);
    std.debug.warn(fmt, args);
}

fn printBlock(ident: usize, block: var, endNewline: bool) void {
    std.debug.warn("(\n");

    for (block.toSlice()) |stmt| {
        printIdent(ident);
        printStmt(ident, stmt);
        std.debug.warn("\n");
    }

    if (endNewline) {
        print(ident - 1, ")\n");
    } else {
        print(ident - 1, ")");
    }
}

pub fn printNode(node: *Node, ident: usize) void {
    switch (node.*) {
        .FnDecl => |decl| {
            print(ident, "(fn {} (", decl.func_name.lexeme);

            for (decl.params.toSlice()) |param| {
                std.debug.warn("({} {}) ", param.name.lexeme, param.typ.lexeme);
            }

            printBlock(ident + 1, decl.body, false);
            std.debug.warn(")\n");
        },

        .ConstDecl => |consts| {
            print(ident, "(const (\n");

            for (consts.toSlice()) |const_decl| {
                print(
                    ident + 1,
                    "({} ",
                    const_decl.name.lexeme,
                );

                printExpr(const_decl.expr);
                std.debug.warn(")\n");
            }

            print(ident, "))\n");
        },

        .Root => {
            for (node.Root.toSlice()) |child| {
                printNode(child, ident + 1);
            }
        },

        .Expr => |expr| {
            printIdent(ident);
            printExpr(expr);
            std.debug.warn("\n");
        },

        .Stmt => |stmt| blk: {
            printIdent(ident);
            printStmt(ident, stmt);
            std.debug.warn("\n");
        },

        else => {
            print(ident, "unknown node: {}\n", node);
        },
    }
}

fn parenthetize(name: []const u8, exprs: []*Expr) void {
    std.debug.warn("({}", name);

    for (exprs) |expr| {
        std.debug.warn(" ");
        printExpr(expr);
    }

    std.debug.warn(")");
}

pub fn printExpr(expr: *Expr) void {
    switch (expr.*) {
        .Binary => |binary| parenthetize(binary.op.lexeme, &[_]*Expr{ binary.left, binary.right }),
        .Logical => |binary| parenthetize(binary.op.lexeme, &[_]*Expr{ binary.left, binary.right }),
        .Unary => |unary| parenthetize(unary.op.lexeme, &[_]*Expr{unary.right}),
        .Grouping => |expr_ptr| parenthetize("group", &[_]*Expr{expr_ptr}),

        .Literal => |literal| {
            switch (literal) {
                .Bool => |val| std.debug.warn("{}", val),
                .Integer => |val| std.debug.warn("{}", val),
                .Float => |val| std.debug.warn("{}", val),
                .String => |val| std.debug.warn("'{}'", val),
            }
        },

        .Variable => |token| std.debug.warn("{}", token.lexeme),

        .VarDecl => |decl| {
            if (decl.mutable) {
                std.debug.warn("(mut ");
            } else {
                std.debug.warn("(");
            }

            std.debug.warn("let {} ", decl.assign.name.lexeme);
            printExpr(decl.assign.value);
            std.debug.warn(")");
        },

        .Assign => |assign| {
            std.debug.warn("(set ");
            std.debug.warn("{} ", assign.name.lexeme);
            printExpr(assign.value);
            std.debug.warn(")");
        },

        .Call => |call| {
            std.debug.warn("(");
            printExpr(call.callee);

            for (call.arguments.toSlice()) |arg| {
                std.debug.warn(" ");
                printExpr(arg);
            }

            std.debug.warn(")");
        },

        else => std.debug.warn("UnknownExpr-{}", @tagName(expr.*)),
    }
}

pub fn printStmt(ident: usize, stmt: *Stmt) void {
    switch (stmt.*) {
        .Println => |expr| parenthetize("println", &[_]*Expr{expr}),
        .Expr => |expr| printExpr(expr),

        .If => |ifstmt| {
            std.debug.warn("(if ");
            printExpr(ifstmt.condition);
            std.debug.warn(" ");

            printBlock(ident + 1, ifstmt.then_branch, false);
            if (ifstmt.else_branch) |else_branch| {
                std.debug.warn(" else ");
                printBlock(ident + 1, else_branch, false);
            }

            std.debug.warn(")\n");
        },

        .Loop => |loop| {
            std.debug.warn("(loop ");
            if (loop.condition) |cond| {
                printExpr(cond);
            } else {
                std.debug.warn("true");
            }
            std.debug.warn(" ");

            printBlock(ident + 1, loop.then_branch, false);
            std.debug.warn(")\n");
        },

        .Return => |ret| {
            std.debug.warn("(return ");
            printExpr(ret.value);
            std.debug.warn(")\n");
        },

        else => std.debug.warn("UnknownStmt-{}", @tagName(stmt.*)),
    }
}