Add ReferenceMockRegistry

spec/spectator/mocks/reference_mock_registry_spec.cr

@@ -0,0 +1,23 @@
+require "../../spec_helper"
+
+Spectator.describe Spectator::ReferenceMockRegistry do
+  subject(registry) { described_class.new }
+  let(stub) { Spectator::ValueStub.new(:test, 42) }
+
+  it "initially has no stubs" do
+    obj = "foobar"
+    expect(registry[obj]).to be_empty
+  end
+
+  it "stores stubs for an object" do
+    obj = "foobar"
+    expect { registry[obj] << stub }.to change { registry[obj] }.from([] of Spectator::Stub).to([stub])
+  end
+
+  it "isolates stubs between different objects" do
+    obj1 = "foo"
+    obj2 = "bar"
+    registry[obj2] << Spectator::ValueStub.new(:obj2, 42)
+    expect { registry[obj1] << stub }.to_not change { registry[obj2] }
+  end
+end

src/spectator/mocks/mock.cr

@@ -1,5 +1,6 @@
 require "./method_call"
 require "./mocked"
+require "./reference_mock_registry"
 require "./stub"
 require "./stubbed_name"
 require "./value_stub"
@@ -51,12 +52,14 @@ module Spectator
         {{base}} ::{{type.name}}
           include ::Spectator::Mocked
 
-          @@_spectator_stubs = Hash(self, Array(::Spectator::Stub)).new do |hash, key|
-            hash[key] = [] of ::Spectator::Stub
-          end
+          {% if type.class? %}
+            @@_spectator_mock_registry = ::Spectator::ReferenceMockRegistry.new
+          {% else %}
+            {% raise "Unsupported type for injecting mock" %}
+          {% end %}
 
           private def _spectator_stubs
-            @@_spectator_stubs[self]
+            @@_spectator_mock_registry[self]
           end
 
           # Returns the mock's name formatted for user output.

src/spectator/mocks/reference_mock_registry.cr

@@ -0,0 +1,27 @@
+require "./stub"
+
+module Spectator
+  # Stores collections of stubs for mocked reference (class) types.
+  #
+  # This type is intended for all mocked reference types that have functionality "injected."
+  # That is, the type itself has mock functionality bolted on.
+  # Adding instance members should be avoided, for instance, it could mess up serialization.
+  # This registry works around that by mapping mocks (via their memory address) to a collection of stubs.
+  # Doing so prevents adding data to the mocked type.
+  class ReferenceMockRegistry
+    @object_stubs : Hash(Void*, Array(Stub))
+
+    # Creates an empty registry.
+    def initialize
+      @object_stubs = Hash(Void*, Array(Stub)).new do |hash, key|
+        hash[key] = [] of Stub
+      end
+    end
+
+    # Retrieves all stubs defined for a mocked object.
+    def [](object : Reference) : Array(Stub)
+      key = Box.box(object)
+      @object_stubs[key]
+    end
+  end
+end