diff --git a/spec/ameba/rule/syntax_spec.cr b/spec/ameba/rule/syntax_spec.cr
new file mode 100644
index 00000000..f8eaf771
--- /dev/null
+++ b/spec/ameba/rule/syntax_spec.cr
@@ -0,0 +1,39 @@
+require "../../spec_helper"
+
+module Ameba::Rule
+  describe Syntax do
+    subject = Syntax.new
+
+    it "passes if there is no invalid syntax" do
+      s = Source.new %(
+        def hello
+          puts "totally valid"
+        rescue e: Exception
+          #
+        end
+      )
+      subject.catch(s).should be_valid
+    end
+
+    it "fails if there is an invalid syntax" do
+      s = Source.new %(
+        def hello
+          puts "invalid"
+        rescue Exception => e
+          #
+        end
+      )
+      subject.catch(s).should_not be_valid
+    end
+
+    it "reports rule, location and message" do
+      s = Source.new "def hello end", "source.cr"
+      subject.catch(s).should_not be_valid
+      error = s.errors.first
+
+      error.rule.should_not be_nil
+      error.location.to_s.should eq "source.cr:1:11"
+      error.message.should eq "unexpected token: end (expected ';' or newline)"
+    end
+  end
+end
diff --git a/src/ameba/rule/syntax.cr b/src/ameba/rule/syntax.cr
new file mode 100644
index 00000000..52feee5e
--- /dev/null
+++ b/src/ameba/rule/syntax.cr
@@ -0,0 +1,35 @@
+module Ameba::Rule
+  # A rule that reports invalid Crystal syntax.
+  #
+  # For example, this syntax is invalid:
+  #
+  # ```
+  # def hello
+  #   do_something
+  # rescue Exception => e
+  # end
+  # ```
+  #
+  # And should be properly written:
+  #
+  # ```
+  # def hello
+  #   do_something
+  # rescue e : Exception
+  # end
+  # ```
+  #
+  struct Syntax < Base
+    properties do
+      enabled = true
+      description = "Reports invalid Crystal syntax"
+    end
+
+    def test(source)
+      source.ast
+    rescue e : Crystal::SyntaxException
+      location = source.location(e.line_number, e.column_number)
+      source.error self, location, e.message.to_s
+    end
+  end
+end