fediglam/src/sql/lib.zig

const std = @import("std");
const util = @import("util");

const postgres = @import("./postgres.zig");
const sqlite = @import("./sqlite.zig");
const common = @import("./common.zig");
const Allocator = std.mem.Allocator;

pub const QueryOptions = common.QueryOptions;

pub const Engine = enum {
    postgres,
    sqlite,
};

pub const Config = union(Engine) {
    postgres: struct {
        pg_conn_str: [:0]const u8,
    },
    sqlite: struct {
        sqlite_file_path: [:0]const u8,
    },
};

//pub const OpenError = sqlite.OpenError | postgres.OpenError;
const RawResults = union(Engine) {
    postgres: postgres.Results,
    sqlite: sqlite.Results,

    fn finish(self: RawResults) void {
        switch (self) {
            .postgres => |pg| pg.finish(),
            .sqlite => |lite| lite.finish(),
        }
    }
};

// Represents a set of results.
// row() must be called until it returns null, or the query may not complete
// Must be deallocated by a call to finish()
pub fn Results(comptime result_types: []const type) type {
    return struct {
        const Self = @This();
        const RowTuple = std.meta.Tuple(result_types);

        underlying: RawResults,

        pub fn finish(self: Self) void {
            self.underlying.finish();
        }

        // can be used as an optimization to reduce memory reallocation
        // only works on postgres
        pub fn rowCount(self: Self) ?usize {
            return switch (self.underlying) {
                .postgres => |pg| pg.rowCount(),
                .sqlite => null, // not possible without repeating the query
            };
        }

        pub fn row(self: *Self, alloc: ?Allocator) !?RowTuple {
            const row_val = switch (self.underlying) {
                .postgres => |*pg| if (try pg.row()) |r| Row{ .postgres = r } else return null,
                .sqlite => |*lite| if (try lite.row()) |r| Row{ .sqlite = r } else return null,
            };

            var result: RowTuple = undefined;
            var fields_allocated = [_]bool{false} ** result.len;
            errdefer {
                inline for (result_types) |_, i| {
                    if (fields_allocated[i]) util.deepFree(alloc, result[i]);
                }
            }
            inline for (result_types) |T, i| {
                result[i] = try row_val.get(T, i, alloc);
                fields_allocated[i] = true;
            }

            return result;
        }
    };
}

// Row is invalidated by the next call to result.row()
const Row = union(Engine) {
    postgres: postgres.Row,
    sqlite: sqlite.Row,

    // Returns a value of type T from the zero-indexed column given by idx.
    // Not all types require an allocator to be present. If an allocator is needed but
    // not required, it will return error.AllocatorRequired.
    // The caller is responsible for deallocating T, if relevant.
    fn get(self: Row, comptime T: type, idx: u15, alloc: ?Allocator) anyerror!T {
        return switch (self) {
            .postgres => |pg| pg.get(T, idx, alloc),
            .sqlite => |lite| lite.get(T, idx, alloc),
        };
    }
};

const DbUnion = union(Engine) {
    postgres: postgres.Db,
    sqlite: sqlite.Db,
};

pub const ConstraintMode = enum {
    deferred,
    immediate,
};

pub const Db = struct {
    tx_open: bool = false,
    underlying: DbUnion,

    pub fn open(cfg: Config) !Db {
        return switch (cfg) {
            .postgres => |postgres_cfg| Db{
                .underlying = .{
                    .postgres = try postgres.Db.open(postgres_cfg.pg_conn_str),
                },
            },
            .sqlite => |lite_cfg| Db{
                .underlying = .{
                    .sqlite = try sqlite.Db.open(lite_cfg.sqlite_file_path),
                },
            },
        };
    }

    pub fn close(self: *Db) void {
        switch (self.underlying) {
            .postgres => |pg| pg.close(),
            .sqlite => |lite| lite.close(),
        }
    }

    pub fn queryWithOptions(
        self: *Db,
        comptime result_types: []const type,
        sql: [:0]const u8,
        args: anytype,
        opt: QueryOptions,
    ) !Results(result_types) {
        if (self.tx_open) return error.TransactionOpen;
        // Create fake transaction to use its functions
        return (Tx{ .db = self }).queryWithOptions(result_types, sql, args, opt);
    }

    pub fn query(
        self: *Db,
        comptime result_types: []const type,
        sql: [:0]const u8,
        args: anytype,
        alloc: ?Allocator,
    ) !Results(result_types) {
        if (self.tx_open) return error.TransactionOpen;
        // Create fake transaction to use its functions
        return (Tx{ .db = self }).query(result_types, sql, args, alloc);
    }

    pub fn exec(
        self: *Db,
        sql: [:0]const u8,
        args: anytype,
        alloc: ?Allocator,
    ) !void {
        if (self.tx_open) return error.TransactionOpen;
        // Create fake transaction to use its functions
        return (Tx{ .db = self }).exec(sql, args, alloc);
    }

    pub fn queryRow(
        self: *Db,
        comptime result_types: []const type,
        sql: [:0]const u8,
        args: anytype,
        alloc: ?Allocator,
    ) !?Results(result_types).RowTuple {
        if (self.tx_open) return error.TransactionOpen;
        // Create fake transaction to use its functions
        return (Tx{ .db = self }).queryRow(result_types, sql, args, alloc);
    }

    pub fn insert(
        self: *Db,
        comptime table: []const u8,
        value: anytype,
    ) !void {
        if (self.tx_open) return error.TransactionOpen;
        // Create fake transaction to use its functions
        return (Tx{ .db = self }).insert(table, value);
    }

    pub fn sqlEngine(self: *Db) Engine {
        return self.underlying;
    }

    // Begins a transaction
    pub fn begin(self: *Db) !Tx {
        const tx = Tx{ .db = self };
        try tx.exec("BEGIN", .{}, null);

        return tx;
    }
};

pub const Tx = struct {
    db: *Db,

    // internal helper fn
    fn queryInternal(
        self: Tx,
        sql: [:0]const u8,
        args: anytype,
        opt: QueryOptions,
    ) !RawResults {
        return switch (self.db.underlying) {
            .postgres => |pg| RawResults{ .postgres = try pg.exec(sql, args, opt.prep_allocator) },
            .sqlite => |lite| RawResults{ .sqlite = try lite.exec(sql, args, opt) },
        };
    }

    pub fn queryWithOptions(
        self: Tx,
        comptime result_types: []const type,
        sql: [:0]const u8,
        args: anytype,
        options: QueryOptions,
    ) !Results(result_types) {
        return Results(result_types){ .underlying = try self.queryInternal(sql, args, options) };
    }

    // Executes a query and returns the result set
    pub fn query(
        self: Tx,
        comptime result_types: []const type,
        sql: [:0]const u8,
        args: anytype,
        alloc: ?Allocator,
    ) !Results(result_types) {
        return self.queryWithOptions(result_types, sql, args, .{ .prep_allocator = alloc });
    }

    // Executes a query without returning results
    pub fn exec(
        self: Tx,
        sql: [:0]const u8,
        args: anytype,
        alloc: ?Allocator,
    ) !void {
        _ = try self.queryRow(&.{}, sql, args, alloc);
    }

    // Runs a query and returns a single row
    pub fn queryRow(
        self: Tx,
        comptime result_types: []const type,
        q: [:0]const u8,
        args: anytype,
        alloc: ?Allocator,
    ) !?Results(result_types).RowTuple {
        var results = try self.query(result_types, q, args, alloc);
        defer results.finish();

        const row = (try results.row(alloc)) orelse return null;
        errdefer util.deepFree(alloc, row);

        var more_rows = false;
        while (try results.row(alloc)) |r| {
            util.deepFree(alloc, r);
            more_rows = true;
        }
        if (more_rows) return error.TooManyRows;

        return row;
    }

    // Inserts a single value into a table
    pub fn insert(
        self: Tx,
        comptime table: []const u8,
        value: anytype,
    ) !void {
        const ValueType = comptime @TypeOf(value);

        const fields = std.meta.fields(ValueType);
        comptime var types: [fields.len]type = undefined;
        comptime var table_spec: []const u8 = table ++ "(";
        comptime var value_spec: []const u8 = "(";
        inline for (fields) |field, i| {
            types[i] = field.field_type;
            table_spec = comptime (table_spec ++ field.name ++ ",");
            value_spec = comptime value_spec ++ std.fmt.comptimePrint("${},", .{i + 1});
        }
        table_spec = comptime table_spec[0 .. table_spec.len - 1] ++ ")";
        value_spec = comptime value_spec[0 .. value_spec.len - 1] ++ ")";
        const q = comptime std.fmt.comptimePrint(
            "INSERT INTO {s} VALUES {s}",
            .{ table_spec, value_spec },
        );

        var args_tuple: std.meta.Tuple(&types) = undefined;
        inline for (fields) |field, i| {
            args_tuple[i] = @field(value, field.name);
        }
        try self.exec(q, args_tuple, null);
    }

    pub fn sqlEngine(self: Tx) Engine {
        return self.db.underlying;
    }

    pub fn setConstraintMode(self: Tx, mode: ConstraintMode) !void {
        switch (self.db.underlying) {
            .sqlite => try self.exec(
                switch (mode) {
                    .immediate => "PRAGMA defer_foreign_keys = FALSE",
                    .deferred => "PRAGMA defer_foreign_keys = TRUE",
                },
                .{},
                null,
            ),
            .postgres => try self.exec(
                switch (mode) {
                    .immediate => "SET CONSTRAINTS ALL IMMEDIATE",
                    .deferred => "SET CONSTRAINTS ALL DEFERRED",
                },
                .{},
                null,
            ),
        }
    }

    pub fn rollback(self: Tx) void {
        self.exec("ROLLBACK", .{}, null) catch |err| {
            std.log.err("Error occured during rollback operation: {}", .{err});
        };
    }

    pub fn commit(self: Tx) !void {
        try self.exec("COMMIT", .{}, null);
    }
};