mirror of
https://git.wownero.com/wownero/wownero.git
synced 2024-08-15 01:03:23 +00:00
This replaces the epee and data_loggers logging systems with a single one, and also adds filename:line and explicit severity levels. Categories may be defined, and logging severity set by category (or set of categories). epee style 0-4 log level maps to a sensible severity configuration. Log files now also rotate when reaching 100 MB. To select which logs to output, use the MONERO_LOGS environment variable, with a comma separated list of categories (globs are supported), with their requested severity level after a colon. If a log matches more than one such setting, the last one in the configuration string applies. A few examples: This one is (mostly) silent, only outputting fatal errors: MONERO_LOGS=*:FATAL This one is very verbose: MONERO_LOGS=*:TRACE This one is totally silent (logwise): MONERO_LOGS="" This one outputs all errors and warnings, except for the "verify" category, which prints just fatal errors (the verify category is used for logs about incoming transactions and blocks, and it is expected that some/many will fail to verify, hence we don't want the spam): MONERO_LOGS=*:WARNING,verify:FATAL Log levels are, in decreasing order of priority: FATAL, ERROR, WARNING, INFO, DEBUG, TRACE Subcategories may be added using prefixes and globs. This example will output net.p2p logs at the TRACE level, but all other net* logs only at INFO: MONERO_LOGS=*:ERROR,net*:INFO,net.p2p:TRACE Logs which are intended for the user (which Monero was using a lot through epee, but really isn't a nice way to go things) should use the "global" category. There are a few helper macros for using this category, eg: MGINFO("this shows up by default") or MGINFO_RED("this is red"), to try to keep a similar look and feel for now. Existing epee log macros still exist, and map to the new log levels, but since they're used as a "user facing" UI element as much as a logging system, they often don't map well to log severities (ie, a log level 0 log may be an error, or may be something we want the user to see, such as an important info). In those cases, I tried to use the new macros. In other cases, I left the existing macros in. When modifying logs, it is probably best to switch to the new macros with explicit levels. The --log-level options and set_log commands now also accept category settings, in addition to the epee style log levels.
672 lines
24 KiB
CMake
672 lines
24 KiB
CMake
# Copyright (c) 2014-2016, The Monero Project
|
|
#
|
|
# All rights reserved.
|
|
#
|
|
# Redistribution and use in source and binary forms, with or without modification, are
|
|
# permitted provided that the following conditions are met:
|
|
#
|
|
# 1. Redistributions of source code must retain the above copyright notice, this list of
|
|
# conditions and the following disclaimer.
|
|
#
|
|
# 2. Redistributions in binary form must reproduce the above copyright notice, this list
|
|
# of conditions and the following disclaimer in the documentation and/or other
|
|
# materials provided with the distribution.
|
|
#
|
|
# 3. Neither the name of the copyright holder nor the names of its contributors may be
|
|
# used to endorse or promote products derived from this software without specific
|
|
# prior written permission.
|
|
#
|
|
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY
|
|
# EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
|
|
# MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL
|
|
# THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
|
|
# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
|
|
# PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
|
|
# INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
|
|
# STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF
|
|
# THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
|
|
#
|
|
# Parts of this file are originally copyright (c) 2012-2013 The Cryptonote developers
|
|
|
|
cmake_minimum_required(VERSION 2.8.7)
|
|
|
|
project(monero)
|
|
|
|
function (die msg)
|
|
if (NOT WIN32)
|
|
string(ASCII 27 Esc)
|
|
set(ColourReset "${Esc}[m")
|
|
set(BoldRed "${Esc}[1;31m")
|
|
else ()
|
|
set(ColourReset "")
|
|
set(BoldRed "")
|
|
endif ()
|
|
|
|
message(FATAL_ERROR "${BoldRed}${msg}${ColourReset}")
|
|
endfunction ()
|
|
|
|
if(NOT CMAKE_BUILD_TYPE)
|
|
set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type" FORCE)
|
|
message(STATUS "Setting default build type: ${CMAKE_BUILD_TYPE}")
|
|
endif()
|
|
string(TOLOWER ${CMAKE_BUILD_TYPE} CMAKE_BUILD_TYPE_LOWER)
|
|
|
|
# ARCH defines the target architecture, either by an explicit identifier or
|
|
# one of the following two keywords. By default, ARCH a value of 'native':
|
|
# target arch = host arch, binary is not portable. When ARCH is set to the
|
|
# string 'default', no -march arg is passed, which creates a binary that is
|
|
# portable across processors in the same family as host processor. In cases
|
|
# when ARCH is not set to an explicit identifier, cmake's builtin is used
|
|
# to identify the target architecture, to direct logic in this cmake script.
|
|
# Since ARCH is a cached variable, it will not be set on first cmake invocation.
|
|
if (NOT ARCH OR ARCH STREQUAL "" OR ARCH STREQUAL "native" OR ARCH STREQUAL "default")
|
|
set(ARCH_ID "${CMAKE_SYSTEM_PROCESSOR}")
|
|
else()
|
|
set(ARCH_ID "${ARCH}")
|
|
endif()
|
|
string(TOLOWER "${ARCH_ID}" ARM_ID)
|
|
string(SUBSTRING "${ARM_ID}" 0 3 ARM_TEST)
|
|
if (ARM_TEST STREQUAL "arm")
|
|
set(ARM 1)
|
|
string(SUBSTRING "${ARM_ID}" 0 5 ARM_TEST)
|
|
if (ARM_TEST STREQUAL "armv6")
|
|
set(ARM6 1)
|
|
endif()
|
|
if (ARM_TEST STREQUAL "armv7")
|
|
set(ARM7 1)
|
|
endif()
|
|
endif()
|
|
|
|
if (ARM_ID STREQUAL "aarch64")
|
|
set(ARM 1)
|
|
set(ARM8 1)
|
|
endif()
|
|
|
|
if(WIN32 OR ARM)
|
|
set(OPT_FLAGS_RELEASE "-O2")
|
|
else()
|
|
set(OPT_FLAGS_RELEASE "-Ofast")
|
|
endif()
|
|
|
|
set(CMAKE_C_FLAGS_RELEASE "-DNDEBUG ${OPT_FLAGS_RELEASE}")
|
|
set(CMAKE_CXX_FLAGS_RELEASE "-DNDEBUG ${OPT_FLAGS_RELEASE}")
|
|
|
|
# set this to 0 if per-block checkpoint needs to be disabled
|
|
set(PER_BLOCK_CHECKPOINT 1)
|
|
|
|
if(PER_BLOCK_CHECKPOINT)
|
|
add_definitions("-DPER_BLOCK_CHECKPOINT")
|
|
endif()
|
|
|
|
list(INSERT CMAKE_MODULE_PATH 0
|
|
"${CMAKE_SOURCE_DIR}/cmake")
|
|
|
|
if (NOT DEFINED ENV{DEVELOPER_LOCAL_TOOLS})
|
|
message(STATUS "Could not find DEVELOPER_LOCAL_TOOLS in env (not required)")
|
|
set(BOOST_IGNORE_SYSTEM_PATHS_DEFAULT OFF)
|
|
elseif ("$ENV{DEVELOPER_LOCAL_TOOLS}" EQUAL 1)
|
|
message(STATUS "Found: env DEVELOPER_LOCAL_TOOLS = 1")
|
|
set(BOOST_IGNORE_SYSTEM_PATHS_DEFAULT ON)
|
|
else()
|
|
message(STATUS "Found: env DEVELOPER_LOCAL_TOOLS = 0")
|
|
set(BOOST_IGNORE_SYSTEM_PATHS_DEFAULT OFF)
|
|
endif()
|
|
|
|
message(STATUS "BOOST_IGNORE_SYSTEM_PATHS defaults to ${BOOST_IGNORE_SYSTEM_PATHS_DEFAULT}")
|
|
option(BOOST_IGNORE_SYSTEM_PATHS "Ignore boost system paths for local boost installation" ${BOOST_IGNORE_SYSTEM_PATHS_DEFAULT})
|
|
|
|
|
|
if (NOT DEFINED ENV{DEVELOPER_LIBUNBOUND_OLD})
|
|
message(STATUS "Could not find DEVELOPER_LIBUNBOUND_OLD in env (not required)")
|
|
elseif ("$ENV{DEVELOPER_LIBUNBOUND_OLD}" EQUAL 1)
|
|
message(STATUS "Found: env DEVELOPER_LIBUNBOUND_OLD = 1, will use the work around")
|
|
add_definitions(-DDEVELOPER_LIBUNBOUND_OLD)
|
|
elseif ("$ENV{DEVELOPER_LIBUNBOUND_OLD}" EQUAL 0)
|
|
message(STATUS "Found: env DEVELOPER_LIBUNBOUND_OLD = 0")
|
|
else()
|
|
message(STATUS "Found: env DEVELOPER_LIBUNBOUND_OLD with bad value. Will NOT use the work around")
|
|
endif()
|
|
|
|
set_property(GLOBAL PROPERTY USE_FOLDERS ON)
|
|
enable_testing()
|
|
|
|
option(BUILD_DOCUMENTATION "Build the Doxygen documentation." ON)
|
|
|
|
# Check whether we're on a 32-bit or 64-bit system
|
|
if(CMAKE_SIZEOF_VOID_P EQUAL "8")
|
|
set(DEFAULT_BUILD_64 ON)
|
|
else()
|
|
set(DEFAULT_BUILD_64 OFF)
|
|
endif()
|
|
option(BUILD_64 "Build for 64-bit? 'OFF' builds for 32-bit." ${DEFAULT_BUILD_64})
|
|
|
|
if(BUILD_64)
|
|
set(ARCH_WIDTH "64")
|
|
else()
|
|
set(ARCH_WIDTH "32")
|
|
endif()
|
|
message(STATUS "Building for a ${ARCH_WIDTH}-bit system")
|
|
|
|
# Check if we're on FreeBSD so we can exclude the local miniupnpc (it should be installed from ports instead)
|
|
# CMAKE_SYSTEM_NAME checks are commonly known, but specifically taken from libsdl's CMakeLists
|
|
if(CMAKE_SYSTEM_NAME MATCHES "kFreeBSD.*|FreeBSD")
|
|
set(FREEBSD TRUE)
|
|
endif()
|
|
|
|
# Check if we're on DragonFly BSD. See the README.md for build instructions.
|
|
if(CMAKE_SYSTEM_NAME MATCHES "DragonFly.*")
|
|
set(DRAGONFLY TRUE)
|
|
endif()
|
|
|
|
# Check if we're on OpenBSD. See the README.md for build instructions.
|
|
if(CMAKE_SYSTEM_NAME MATCHES "kOpenBSD.*|OpenBSD.*")
|
|
set(OPENBSD TRUE)
|
|
endif()
|
|
|
|
# TODO: check bsdi, NetBSD, to see if they need the same FreeBSD changes
|
|
#
|
|
# elseif(CMAKE_SYSTEM_NAME MATCHES "kNetBSD.*|NetBSD.*")
|
|
# set(NETBSD TRUE)
|
|
# elseif(CMAKE_SYSTEM_NAME MATCHES ".*BSDI.*")
|
|
# set(BSDI TRUE)
|
|
|
|
include_directories(external/easylogging++ src contrib/epee/include external "${CMAKE_BINARY_DIR}/version")
|
|
|
|
if(APPLE)
|
|
include_directories(SYSTEM /usr/include/malloc)
|
|
if(POLICY CMP0042)
|
|
cmake_policy(SET CMP0042 NEW)
|
|
endif()
|
|
endif()
|
|
|
|
if(MSVC OR MINGW)
|
|
set(DEFAULT_STATIC true)
|
|
else()
|
|
set(DEFAULT_STATIC false)
|
|
endif()
|
|
option(STATIC "Link libraries statically" ${DEFAULT_STATIC})
|
|
|
|
# This is a CMake built-in switch that concerns internal libraries
|
|
if (NOT DEFINED BUILD_SHARED_LIBS AND NOT STATIC AND CMAKE_BUILD_TYPE_LOWER STREQUAL "debug")
|
|
set(BUILD_SHARED_LIBS ON)
|
|
endif()
|
|
|
|
if (BUILD_SHARED_LIBS)
|
|
message(STATUS "Building internal libraries with position independent code")
|
|
set(PIC_FLAG "-fPIC")
|
|
else()
|
|
message(STATUS "Building internal libraries as static")
|
|
endif()
|
|
|
|
if(MINGW)
|
|
string(REGEX MATCH "^[^/]:/[^/]*" msys2_install_path "${CMAKE_C_COMPILER}")
|
|
message(STATUS "MSYS location: ${msys2_install_path}")
|
|
set(CMAKE_INCLUDE_PATH "${msys2_install_path}/mingw${ARCH_WIDTH}/include")
|
|
# This is necessary because otherwise CMake will make Boost libraries -lfoo
|
|
# rather than a full path. Unfortunately, this makes the shared libraries get
|
|
# linked due to a bug in CMake which misses putting -static flags around the
|
|
# -lfoo arguments.
|
|
set(DEFLIB ${msys2_install_path}/mingw${ARCH_WIDTH}/lib)
|
|
list(REMOVE_ITEM CMAKE_C_IMPLICIT_LINK_DIRECTORIES ${DEFLIB})
|
|
list(REMOVE_ITEM CMAKE_CXX_IMPLICIT_LINK_DIRECTORIES ${DEFLIB})
|
|
endif()
|
|
|
|
if(STATIC)
|
|
if(MSVC)
|
|
set(CMAKE_FIND_LIBRARY_SUFFIXES .lib .dll.a .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
|
|
else()
|
|
set(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
|
|
endif()
|
|
endif()
|
|
|
|
# default database:
|
|
# should be lmdb for testing, memory for production still
|
|
# set(DATABASE memory)
|
|
set(DATABASE lmdb)
|
|
|
|
if (DEFINED ENV{DATABASE})
|
|
set(DATABASE $ENV{DATABASE})
|
|
message(STATUS "DATABASE set: ${DATABASE}")
|
|
else()
|
|
message(STATUS "Could not find DATABASE in env (not required unless you want to change database type from default: ${DATABASE})")
|
|
endif()
|
|
|
|
set(BERKELEY_DB_OVERRIDE 0)
|
|
if (DEFINED ENV{BERKELEY_DB})
|
|
set(BERKELEY_DB_OVERRIDE 1)
|
|
set(BERKELEY_DB $ENV{BERKELEY_DB})
|
|
elseif()
|
|
set(BERKELEY_DB 0)
|
|
endif()
|
|
|
|
if (DATABASE STREQUAL "lmdb")
|
|
message(STATUS "Using LMDB as default DB type")
|
|
set(BLOCKCHAIN_DB DB_LMDB)
|
|
add_definitions("-DDEFAULT_DB_TYPE=\"lmdb\"")
|
|
elseif (DATABASE STREQUAL "berkeleydb")
|
|
find_package(BerkeleyDB)
|
|
if(NOT BERKELEY_DB)
|
|
die("Found BerkeleyDB includes, but could not find BerkeleyDB library. Please make sure you have installed libdb and libdb-dev / libdb++-dev or the equivalent.")
|
|
else()
|
|
message(STATUS "Found BerkeleyDB include (db.h) in ${BERKELEY_DB_INCLUDE_DIR}")
|
|
if(BERKELEY_DB_LIBRARIES)
|
|
message(STATUS "Found BerkeleyDB shared library")
|
|
set(BDB_STATIC false CACHE BOOL "BDB Static flag")
|
|
set(BDB_INCLUDE ${BERKELEY_DB_INCLUDE_DIR} CACHE STRING "BDB include path")
|
|
set(BDB_LIBRARY ${BERKELEY_DB_LIBRARIES} CACHE STRING "BDB library name")
|
|
set(BDB_LIBRARY_DIRS "" CACHE STRING "BDB Library dirs")
|
|
set(BERKELEY_DB 1)
|
|
else()
|
|
die("Found BerkeleyDB includes, but could not find BerkeleyDB library. Please make sure you have installed libdb and libdb-dev / libdb++-dev or the equivalent.")
|
|
endif()
|
|
endif()
|
|
|
|
message(STATUS "Using Berkeley DB as default DB type")
|
|
add_definitions("-DDEFAULT_DB_TYPE=\"berkeley\"")
|
|
else()
|
|
die("Invalid database type: ${DATABASE}")
|
|
endif()
|
|
|
|
if(BERKELEY_DB)
|
|
add_definitions("-DBERKELEY_DB")
|
|
endif()
|
|
|
|
add_definitions("-DBLOCKCHAIN_DB=${BLOCKCHAIN_DB}")
|
|
|
|
# Can't install hook in static build on OSX, because OSX linker does not support --wrap
|
|
# On ARM, having libunwind package (with .so's only) installed breaks static link.
|
|
if(APPLE OR (ARM AND STATIC))
|
|
set(DEFAULT_STACK_TRACE OFF)
|
|
set(LIBUNWIND_LIBRARIES "")
|
|
else()
|
|
find_package(Libunwind)
|
|
if(LIBUNWIND_FOUND)
|
|
set(DEFAULT_STACK_TRACE ON)
|
|
else()
|
|
set(DEFAULT_STACK_TRACE OFF)
|
|
set(LIBUNWIND_LIBRARIES "")
|
|
endif()
|
|
endif()
|
|
|
|
option(STACK_TRACE "Install a hook that dumps stack on exception" ${DEFAULT_STACK_TRACE})
|
|
|
|
if(STACK_TRACE)
|
|
message(STATUS "Stack trace on exception enabled")
|
|
else()
|
|
message(STATUS "Stack trace on exception disabled")
|
|
endif()
|
|
|
|
if (UNIX AND NOT APPLE)
|
|
# Note that at the time of this writing the -Wstrict-prototypes flag added below will make this fail
|
|
set(THREADS_PREFER_PTHREAD_FLAG ON)
|
|
find_package(Threads)
|
|
endif()
|
|
|
|
add_subdirectory(external)
|
|
|
|
# Final setup for miniupnpc
|
|
if(UPNP_STATIC)
|
|
add_definitions("-DUPNP_STATIC")
|
|
else()
|
|
add_definitions("-DUPNP_DYNAMIC")
|
|
include_directories(${UPNP_INCLUDE})
|
|
endif()
|
|
|
|
# Final setup for libunbound
|
|
include_directories(${UNBOUND_INCLUDE})
|
|
link_directories(${UNBOUND_LIBRARY_DIRS})
|
|
|
|
# Final setup for rapidjson
|
|
include_directories(external/rapidjson)
|
|
|
|
# Final setup for liblmdb
|
|
include_directories(${LMDB_INCLUDE})
|
|
|
|
# Final setup for Berkeley DB
|
|
if (BERKELEY_DB)
|
|
include_directories(${BDB_INCLUDE})
|
|
endif()
|
|
|
|
# Final setup for libunwind
|
|
include_directories(${LIBUNWIND_INCLUDE})
|
|
link_directories(${LIBUNWIND_LIBRARY_DIRS})
|
|
|
|
if(MSVC)
|
|
add_definitions("/bigobj /MP /W3 /GS- /D_CRT_SECURE_NO_WARNINGS /wd4996 /wd4345 /D_WIN32_WINNT=0x0600 /DWIN32_LEAN_AND_MEAN /DGTEST_HAS_TR1_TUPLE=0 /FIinline_c.h /D__SSE4_1__")
|
|
# set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /Dinline=__inline")
|
|
set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10485760")
|
|
if(STATIC)
|
|
foreach(VAR CMAKE_C_FLAGS_DEBUG CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS_RELEASE)
|
|
string(REPLACE "/MD" "/MT" ${VAR} "${${VAR}}")
|
|
endforeach()
|
|
endif()
|
|
include_directories(SYSTEM src/platform/msc)
|
|
else()
|
|
include(TestCXXAcceptsFlag)
|
|
set(ARCH native CACHE STRING "CPU to build for: -march value or 'default' to not pass -march at all")
|
|
message(STATUS "Building on ${CMAKE_SYSTEM_PROCESSOR} for ${ARCH}")
|
|
if(ARCH STREQUAL "default")
|
|
set(ARCH_FLAG "")
|
|
else()
|
|
set(ARCH_FLAG "-march=${ARCH}")
|
|
endif()
|
|
set(WARNINGS "-Wall -Wextra -Wpointer-arith -Wundef -Wvla -Wwrite-strings -Wno-error=extra -Wno-error=deprecated-declarations -Wno-unused-parameter -Wno-unused-variable -Wno-error=unused-variable -Wno-error=undef -Wno-error=uninitialized")
|
|
if(NOT MINGW)
|
|
set(WARNINGS_AS_ERRORS_FLAG "-Werror")
|
|
endif()
|
|
if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
|
|
if(ARM)
|
|
set(WARNINGS "${WARNINGS} -Wno-error=inline-asm")
|
|
endif()
|
|
else()
|
|
set(WARNINGS "${WARNINGS} -Wlogical-op -Wno-error=maybe-uninitialized")
|
|
endif()
|
|
if(MINGW)
|
|
set(WARNINGS "${WARNINGS} -Wno-error=unused-value -Wno-error=unused-but-set-variable")
|
|
set(MINGW_FLAG "${MINGW_FLAG} -DWIN32_LEAN_AND_MEAN")
|
|
set(Boost_THREADAPI win32)
|
|
include_directories(SYSTEM src/platform/mingw)
|
|
# mingw doesn't support LTO (multiple definition errors at link time)
|
|
set(USE_LTO_DEFAULT false)
|
|
set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,10485760")
|
|
if(NOT BUILD_64)
|
|
add_definitions(-DWINVER=0x0501 -D_WIN32_WINNT=0x0501)
|
|
endif()
|
|
endif()
|
|
set(C_WARNINGS "-Waggregate-return -Wnested-externs -Wold-style-definition -Wstrict-prototypes")
|
|
set(CXX_WARNINGS "-Wno-reorder -Wno-missing-field-initializers")
|
|
try_compile(STATIC_ASSERT_RES "${CMAKE_CURRENT_BINARY_DIR}/static-assert" "${CMAKE_CURRENT_SOURCE_DIR}/cmake/test-static-assert.c" COMPILE_DEFINITIONS "-std=c11")
|
|
if(STATIC_ASSERT_RES)
|
|
set(STATIC_ASSERT_FLAG "")
|
|
else()
|
|
set(STATIC_ASSERT_FLAG "-Dstatic_assert=_Static_assert")
|
|
endif()
|
|
|
|
try_compile(STATIC_ASSERT_CPP_RES "${CMAKE_CURRENT_BINARY_DIR}/static-assert" "${CMAKE_CURRENT_SOURCE_DIR}/cmake/test-static-assert.cpp" COMPILE_DEFINITIONS "-std=c++11")
|
|
if(STATIC_ASSERT_CPP_RES)
|
|
set(STATIC_ASSERT_CPP_FLAG "")
|
|
else()
|
|
set(STATIC_ASSERT_CPP_FLAG "-Dstatic_assert=_Static_assert")
|
|
endif()
|
|
|
|
option(COVERAGE "Enable profiling for test coverage report" 0)
|
|
|
|
if(COVERAGE)
|
|
message(STATUS "Building with profiling for test coverage report")
|
|
set(COVERAGE_FLAGS "-fprofile-arcs -ftest-coverage --coverage")
|
|
endif()
|
|
|
|
# With GCC 6.1.1 the compiled binary malfunctions due to aliasing. Until that
|
|
# is fixed in the code (Issue #847), force compiler to be conservative.
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fno-strict-aliasing")
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing")
|
|
|
|
option(NO_AES "Explicitly disable AES support" ${NO_AES})
|
|
|
|
if(NOT NO_AES AND NOT ARM)
|
|
message(STATUS "AES support enabled")
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -maes")
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -maes")
|
|
elseif(ARM6)
|
|
message(STATUS "AES support not available on ARMv6")
|
|
elseif(ARM7)
|
|
message(STATUS "AES support not available on ARMv7")
|
|
elseif(ARM8)
|
|
CHECK_CXX_ACCEPTS_FLAG("-march=${ARCH}+crypto" ARCH_PLUS_CRYPTO)
|
|
if(ARCH_PLUS_CRYPTO)
|
|
message(STATUS "Crypto extensions enabled for ARMv8")
|
|
set(ARCH_FLAG "-march=${ARCH}+crypto")
|
|
else()
|
|
message(STATUS "Crypto extensions unavailable on your ARMv8 device")
|
|
endif()
|
|
else()
|
|
message(STATUS "AES support disabled")
|
|
endif()
|
|
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c11 -D_GNU_SOURCE ${MINGW_FLAG} ${STATIC_ASSERT_FLAG} ${WARNINGS} ${C_WARNINGS} ${ARCH_FLAG} ${COVERAGE_FLAGS} ${PIC_FLAG}")
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -D_GNU_SOURCE ${MINGW_FLAG} ${STATIC_ASSERT_CPP_FLAG} ${WARNINGS} ${CXX_WARNINGS} ${ARCH_FLAG} ${COVERAGE_FLAGS} ${PIC_FLAG}")
|
|
|
|
# With GCC 6.1.1 the compiled binary malfunctions due to aliasing. Until that
|
|
# is fixed in the code (Issue #847), force compiler to be conservative.
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fno-strict-aliasing")
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing")
|
|
|
|
if(ARM)
|
|
message(STATUS "Setting FPU Flags for ARM Processors")
|
|
|
|
#NB NEON hardware does not fully implement the IEEE 754 standard for floating-point arithmetic
|
|
#Need custom assembly code to take full advantage of NEON SIMD
|
|
|
|
#Cortex-A5/9 -mfpu=neon-fp16
|
|
#Cortex-A7/15 -mfpu=neon-vfpv4
|
|
#Cortex-A8 -mfpu=neon
|
|
#ARMv8 -FP and SIMD on by default for all ARM8v-A series, NO -mfpu setting needed
|
|
|
|
#For custom -mtune, processor IDs for ARMv8-A series:
|
|
#0xd04 - Cortex-A35
|
|
#0xd07 - Cortex-A57
|
|
#0xd08 - Cortex-A72
|
|
#0xd03 - Cortex-A73
|
|
|
|
if(NOT ARM8)
|
|
CHECK_CXX_ACCEPTS_FLAG(-mfpu=vfp3-d16 CXX_ACCEPTS_VFP3_D16)
|
|
CHECK_CXX_ACCEPTS_FLAG(-mfpu=vfp4 CXX_ACCEPTS_VFP4)
|
|
CHECK_CXX_ACCEPTS_FLAG(-mfloat-abi=hard CXX_ACCEPTS_MFLOAT_HARD)
|
|
CHECK_CXX_ACCEPTS_FLAG(-mfloat-abi=softfp CXX_ACCEPTS_MFLOAT_SOFTFP)
|
|
endif()
|
|
|
|
if(ARM8)
|
|
CHECK_CXX_ACCEPTS_FLAG(-mfix-cortex-a53-835769 CXX_ACCEPTS_MFIX_CORTEX_A53_835769)
|
|
CHECK_CXX_ACCEPTS_FLAG(-mfix-cortex-a53-843419 CXX_ACCEPTS_MFIX_CORTEX_A53_843419)
|
|
endif()
|
|
|
|
if(ARM6)
|
|
message(STATUS "Selecting VFP for ARMv6")
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mfpu=vfp")
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mfpu=vfp")
|
|
endif(ARM6)
|
|
|
|
if(ARM7)
|
|
if(CXX_ACCEPTS_VFP3_D16 AND NOT CXX_ACCEPTS_VFP4)
|
|
message(STATUS "Selecting VFP3 for ARMv7")
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mfpu=vfp3-d16")
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mfpu=vfp3-d16")
|
|
endif()
|
|
|
|
if(CXX_ACCEPTS_VFP4)
|
|
message(STATUS "Selecting VFP4 for ARMv7")
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mfpu=vfp4")
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mfpu=vfp4")
|
|
endif()
|
|
|
|
if(CXX_ACCEPTS_MFLOAT_HARD)
|
|
message(STATUS "Setting Hardware ABI for Floating Point")
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mfloat-abi=hard")
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mfloat-abi=hard")
|
|
endif()
|
|
|
|
if(CXX_ACCEPTS_MFLOAT_SOFTFP AND NOT CXX_ACCEPTS_MFLOAT_HARD)
|
|
message(STATUS "Setting Software ABI for Floating Point")
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mfloat-abi=softfp")
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mfloat-abi=softfp")
|
|
endif()
|
|
endif(ARM7)
|
|
|
|
if(ARM8)
|
|
if(CXX_ACCEPTS_MFIX_CORTEX_A53_835769)
|
|
message(STATUS "Enabling Cortex-A53 workaround 835769")
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mfix-cortex-a53-835769")
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mfix-cortex-a53-835769")
|
|
endif()
|
|
|
|
if(CXX_ACCEPTS_MFIX_CORTEX_A53_843419)
|
|
message(STATUS "Enabling Cortex-A53 workaround 843419")
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mfix-cortex-a53-843419")
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mfix-cortex-a53-843419")
|
|
endif()
|
|
endif(ARM8)
|
|
|
|
endif(ARM)
|
|
|
|
if(ANDROID AND NOT BUILD_GUI_DEPS STREQUAL "ON")
|
|
#From Android 5: "only position independent executables (PIE) are supported"
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIE")
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIE")
|
|
set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_CXX_FLAGS} -fPIE -pie")
|
|
endif()
|
|
|
|
if(APPLE)
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DGTEST_HAS_TR1_TUPLE=0")
|
|
endif()
|
|
|
|
set(DEBUG_FLAGS "-g3")
|
|
if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND NOT (CMAKE_C_COMPILER_VERSION VERSION_LESS 4.8))
|
|
set(DEBUG_FLAGS "${DEBUG_FLAGS} -Og ")
|
|
else()
|
|
set(DEBUG_FLAGS "${DEBUG_FLAGS} -O0 ")
|
|
endif()
|
|
|
|
if(NOT DEFINED USE_LTO_DEFAULT)
|
|
set(USE_LTO_DEFAULT true)
|
|
endif()
|
|
set(USE_LTO ${USE_LTO_DEFAULT} CACHE BOOL "Use Link-Time Optimization (Release mode only)")
|
|
|
|
if(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
|
|
# There is a clang bug that does not allow to compile code that uses AES-NI intrinsics if -flto is enabled, so explicitly disable
|
|
set(USE_LTO false)
|
|
endif()
|
|
|
|
|
|
if(USE_LTO)
|
|
set(RELEASE_FLAGS "${RELEASE_FLAGS} -flto")
|
|
if(STATIC)
|
|
set(RELEASE_FLAGS "${RELEASE_FLAGS} -ffat-lto-objects")
|
|
endif()
|
|
# Since gcc 4.9 the LTO format is non-standard (slim), so we need the gcc-specific ar and ranlib binaries
|
|
if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.9.0) AND NOT OPENBSD AND NOT DRAGONFLY)
|
|
# When invoking cmake on distributions on which gcc's binaries are prefixed
|
|
# with an arch-specific triplet, the user must specify -DCHOST=<prefix>
|
|
if (DEFINED CHOST)
|
|
set(CMAKE_AR "${CHOST}-gcc-ar")
|
|
set(CMAKE_RANLIB "${CHOST}-gcc-ranlib")
|
|
else()
|
|
set(CMAKE_AR "gcc-ar")
|
|
set(CMAKE_RANLIB "gcc-ranlib")
|
|
endif()
|
|
endif()
|
|
endif()
|
|
|
|
set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} ${DEBUG_FLAGS}")
|
|
set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} ${DEBUG_FLAGS}")
|
|
set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${RELEASE_FLAGS}")
|
|
set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${RELEASE_FLAGS}")
|
|
|
|
if(STATIC)
|
|
# STATIC already configures most deps to be linked in statically,
|
|
# here we make more deps static if the platform permits it
|
|
if (MINGW)
|
|
# On Windows, this is as close to fully-static as we get:
|
|
# this leaves only deps on /c/Windows/system32/*.dll
|
|
set(STATIC_FLAGS "-static")
|
|
elseif (NOT (APPLE OR FREEBSD OR OPENBSD OR DRAGONFLY))
|
|
# On Linux, we don't support fully static build, but these can be static
|
|
set(STATIC_FLAGS "-static-libgcc -static-libstdc++")
|
|
endif()
|
|
set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${STATIC_FLAGS} ")
|
|
endif()
|
|
endif()
|
|
|
|
if (${BOOST_IGNORE_SYSTEM_PATHS} STREQUAL "ON")
|
|
set(Boost_NO_SYSTEM_PATHS TRUE)
|
|
endif()
|
|
|
|
set(OLD_LIB_SUFFIXES ${CMAKE_FIND_LIBRARY_SUFFIXES})
|
|
if(STATIC)
|
|
if(MINGW)
|
|
set(CMAKE_FIND_LIBRARY_SUFFIXES .a)
|
|
endif()
|
|
|
|
set(Boost_USE_STATIC_LIBS ON)
|
|
set(Boost_USE_STATIC_RUNTIME ON)
|
|
endif()
|
|
find_package(Boost 1.58 QUIET REQUIRED COMPONENTS system filesystem thread date_time chrono regex serialization program_options)
|
|
|
|
set(CMAKE_FIND_LIBRARY_SUFFIXES ${OLD_LIB_SUFFIXES})
|
|
if(NOT Boost_FOUND)
|
|
die("Could not find Boost libraries, please make sure you have installed Boost or libboost-all-dev (1.58) or the equivalent")
|
|
elseif(Boost_FOUND)
|
|
message(STATUS "Found Boost Version: ${Boost_VERSION}")
|
|
endif()
|
|
|
|
include_directories(SYSTEM ${Boost_INCLUDE_DIRS})
|
|
if(MINGW)
|
|
set(EXTRA_LIBRARIES mswsock;ws2_32;iphlpapi)
|
|
elseif(APPLE OR FREEBSD OR OPENBSD OR ANDROID)
|
|
set(EXTRA_LIBRARIES "")
|
|
elseif(DRAGONFLY)
|
|
find_library(COMPAT compat)
|
|
set(EXTRA_LIBRARIES ${COMPAT})
|
|
elseif(NOT MSVC)
|
|
find_library(RT rt)
|
|
set(EXTRA_LIBRARIES ${RT})
|
|
endif()
|
|
|
|
list(APPEND EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
|
|
|
|
if(CMAKE_C_COMPILER_ID STREQUAL "Clang" AND ARCH_WIDTH EQUAL "32")
|
|
find_library(ATOMIC atomic)
|
|
list(APPEND EXTRA_LIBRARIES ${ATOMIC})
|
|
endif()
|
|
|
|
include(version.cmake)
|
|
|
|
function (treat_warnings_as_errors dirs)
|
|
foreach(dir ${ARGV})
|
|
set_property(DIRECTORY ${dir}
|
|
APPEND PROPERTY COMPILE_FLAGS "-Werror")
|
|
endforeach()
|
|
endfunction()
|
|
|
|
add_subdirectory(contrib)
|
|
add_subdirectory(src)
|
|
|
|
treat_warnings_as_errors(contrib src)
|
|
|
|
option(BUILD_TESTS "Build tests." OFF)
|
|
|
|
if(BUILD_TESTS)
|
|
add_subdirectory(tests)
|
|
endif()
|
|
|
|
|
|
|
|
if(BUILD_DOCUMENTATION)
|
|
set(DOC_GRAPHS "YES" CACHE STRING "Create dependency graphs (needs graphviz)")
|
|
set(DOC_FULLGRAPHS "NO" CACHE STRING "Create call/callee graphs (large)")
|
|
|
|
find_program(DOT_PATH dot)
|
|
|
|
if (DOT_PATH STREQUAL "DOT_PATH-NOTFOUND")
|
|
message("Doxygen: graphviz not found - graphs disabled")
|
|
set(DOC_GRAPHS "NO")
|
|
endif()
|
|
|
|
find_package(Doxygen)
|
|
if(DOXYGEN_FOUND)
|
|
configure_file("cmake/Doxyfile.in" "Doxyfile" @ONLY)
|
|
configure_file("cmake/Doxygen.extra.css.in" "Doxygen.extra.css" @ONLY)
|
|
add_custom_target(doc
|
|
${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
|
|
COMMENT "Generating API documentation with Doxygen.." VERBATIM)
|
|
endif()
|
|
endif()
|
|
|
|
# when ON - will install libwallet_merged into "lib"
|
|
option(BUILD_GUI_DEPS "Build GUI dependencies." OFF)
|
|
|
|
# This is not nice, distribution packagers should not enable this, but depend
|
|
# on libunbound shipped with their distribution instead
|
|
option(INSTALL_VENDORED_LIBUNBOUND "Install libunbound binary built from source vendored with this repo." OFF)
|
|
|
|
|