device/trezor: webusb transport added, cmake fixes

- webusb transport based on libusb added. Provides direct access to Trezor via USB, no need for Trezor bridge.
- trezor protocol message handler improved, no recursion used. Ready for upcoming integration tests.
- libusb (for docker) bumped from v1.0.9 to v1.0.22, newer version required for webusb transport, for device enumeration.
- cmake improvements and fixes. Cmake Trezor checks are moved to a dedicated CheckTrezor.cmake file. In case of a problem Trezor is excluded from build.
- ifdefs made consistent to Ledger.
- UDP Transport enumeration disabled by default in release mode

cmake/CheckTrezor.cmake

@@ -0,0 +1,79 @@
+OPTION(USE_DEVICE_TREZOR "Trezor support compilation" ON)
+OPTION(USE_DEVICE_TREZOR_LIBUSB "Trezor LibUSB compilation" ON)
+OPTION(USE_DEVICE_TREZOR_UDP_RELEASE "Trezor UdpTransport in release mode" OFF)
+
+# Use Trezor master switch
+if (USE_DEVICE_TREZOR)
+    # Protobuf is required to build protobuf messages for Trezor
+    include(FindProtobuf OPTIONAL)
+    find_package(Protobuf)
+    if(NOT Protobuf_FOUND)
+        message(STATUS "Could not find Protobuf")
+    endif()
+
+else()
+    message(STATUS "Trezor support disabled by USE_DEVICE_TREZOR")
+endif()
+
+if(Protobuf_FOUND AND USE_DEVICE_TREZOR)
+    if (NOT "$ENV{TREZOR_PYTHON}" STREQUAL "")
+        set(TREZOR_PYTHON "$ENV{TREZOR_PYTHON}" CACHE INTERNAL "Copied from environment variable TREZOR_PYTHON")
+    else()
+        find_package(Python QUIET COMPONENTS Interpreter)  # cmake 3.12+
+        if(Python_Interpreter_FOUND)
+            set(TREZOR_PYTHON "${Python_EXECUTABLE}")
+        endif()
+    endif()
+
+    if(NOT TREZOR_PYTHON)
+        find_package(PythonInterp)
+        if(PYTHONINTERP_FOUND AND PYTHON_EXECUTABLE)
+            set(TREZOR_PYTHON "${PYTHON_EXECUTABLE}")
+        endif()
+    endif()
+
+    if(NOT TREZOR_PYTHON)
+        message(STATUS "Trezor: Python not found")
+    endif()
+endif()
+
+# Try to build protobuf messages
+if(Protobuf_FOUND AND USE_DEVICE_TREZOR AND TREZOR_PYTHON)
+    set(ENV{PROTOBUF_INCLUDE_DIRS} "${Protobuf_INCLUDE_DIRS}")
+    set(ENV{PROTOBUF_PROTOC_EXECUTABLE} "${Protobuf_PROTOC_EXECUTABLE}")
+    execute_process(COMMAND ${TREZOR_PYTHON} tools/build_protob.py WORKING_DIRECTORY ${CMAKE_CURRENT_LIST_DIR}/../src/device_trezor/trezor RESULT_VARIABLE RET OUTPUT_VARIABLE OUT ERROR_VARIABLE ERR)
+    if(RET)
+        message(WARNING "Trezor protobuf messages could not be regenerated (err=${RET}, python ${PYTHON})."
+                "OUT: ${OUT}, ERR: ${ERR}."
+                "Please read src/device_trezor/trezor/tools/README.md")
+    else()
+        message(STATUS "Trezor protobuf messages regenerated ${OUT}")
+        set(DEVICE_TREZOR_READY 1)
+        add_definitions(-DDEVICE_TREZOR_READY=1)
+
+        if(CMAKE_BUILD_TYPE STREQUAL "Debug")
+            add_definitions(-DTREZOR_DEBUG=1)
+        endif()
+
+        if(USE_DEVICE_TREZOR_UDP_RELEASE)
+            add_definitions(-DWITH_DEVICE_TREZOR_UDP_RELEASE=1)
+        endif()
+
+        if (Protobuf_INCLUDE_DIR)
+            include_directories(${Protobuf_INCLUDE_DIR})
+        endif()
+
+        # LibUSB support, check for particular version
+        # Include support only if compilation test passes
+        if (USE_DEVICE_TREZOR_LIBUSB)
+            find_package(LibUSB)
+        endif()
+
+        if (LibUSB_COMPILE_TEST_PASSED)
+            add_definitions(-DHAVE_TREZOR_LIBUSB=1)
+            if(LibUSB_INCLUDE_DIRS)
+                include_directories(${LibUSB_INCLUDE_DIRS})
+            endif()
+        endif()
+    endif()
+endif()

cmake/FindLibUSB.cmake

@@ -0,0 +1,140 @@
+# - Find libusb for portable USB support
+# This module will find libusb as published by
+#  http://libusb.sf.net and
+#  http://libusb-win32.sf.net
+#
+# It will use PkgConfig if present and supported, else search
+# it on its own. If the LibUSB_ROOT_DIR environment variable
+# is defined, it will be used as base path.
+# The following standard variables get defined:
+#  LibUSB_FOUND:        true if LibUSB was found
+#  LibUSB_HEADER_FILE:  the location of the C header file
+#  LibUSB_INCLUDE_DIRS: the directory that contains the include file
+#  LibUSB_LIBRARIES:    the library
+# source: https://github.com/IntelRealSense/librealsense
+
+include ( CheckLibraryExists )
+include ( CheckIncludeFile )
+
+find_package ( PkgConfig )
+if ( PKG_CONFIG_FOUND )
+    pkg_check_modules ( PKGCONFIG_LIBUSB libusb-1.0 )
+    if ( NOT PKGCONFIG_LIBUSB_FOUND )
+        pkg_check_modules ( PKGCONFIG_LIBUSB libusb )
+    endif ( NOT PKGCONFIG_LIBUSB_FOUND )
+endif ( PKG_CONFIG_FOUND )
+
+if ( PKGCONFIG_LIBUSB_FOUND )
+    set ( LibUSB_INCLUDE_DIRS ${PKGCONFIG_LIBUSB_INCLUDE_DIRS} )
+    foreach ( i ${PKGCONFIG_LIBUSB_LIBRARIES} )
+        string ( REGEX MATCH "[^-]*" ibase "${i}" )
+        find_library ( ${ibase}_LIBRARY
+                NAMES ${i}
+                PATHS ${PKGCONFIG_LIBUSB_LIBRARY_DIRS}
+                )
+        if ( ${ibase}_LIBRARY )
+            list ( APPEND LibUSB_LIBRARIES ${${ibase}_LIBRARY} )
+        endif ( ${ibase}_LIBRARY )
+        mark_as_advanced ( ${ibase}_LIBRARY )
+    endforeach ( i )
+
+else ( PKGCONFIG_LIBUSB_FOUND )
+    find_file ( LibUSB_HEADER_FILE
+            NAMES
+            libusb.h usb.h
+            PATHS
+            $ENV{ProgramFiles}/LibUSB-Win32
+            $ENV{LibUSB_ROOT_DIR}
+            PATH_SUFFIXES
+            include
+            libusb-1.0
+            include/libusb-1.0
+            )
+    mark_as_advanced ( LibUSB_HEADER_FILE )
+    get_filename_component ( LibUSB_INCLUDE_DIRS "${LibUSB_HEADER_FILE}" PATH )
+
+    if ( ${CMAKE_SYSTEM_NAME} STREQUAL "Windows" )
+        # LibUSB-Win32 binary distribution contains several libs.
+        # Use the lib that got compiled with the same compiler.
+        if ( MSVC )
+            if ( WIN32 )
+                set ( LibUSB_LIBRARY_PATH_SUFFIX lib/msvc )
+            else ( WIN32 )
+                set ( LibUSB_LIBRARY_PATH_SUFFIX lib/msvc_x64 )
+            endif ( WIN32 )
+        elseif ( BORLAND )
+            set ( LibUSB_LIBRARY_PATH_SUFFIX lib/bcc )
+        elseif ( CMAKE_COMPILER_IS_GNUCC )
+            set ( LibUSB_LIBRARY_PATH_SUFFIX lib/gcc )
+        endif ( MSVC )
+    endif ( ${CMAKE_SYSTEM_NAME} STREQUAL "Windows" )
+
+    find_library ( usb_LIBRARY
+            NAMES
+            usb-1.0 libusb usb
+            PATHS
+            $ENV{ProgramFiles}/LibUSB-Win32
+            $ENV{LibUSB_ROOT_DIR}
+            PATH_SUFFIXES
+            ${LibUSB_LIBRARY_PATH_SUFFIX}
+            )
+    mark_as_advanced ( usb_LIBRARY )
+    if ( usb_LIBRARY )
+        set ( LibUSB_LIBRARIES ${usb_LIBRARY} )
+    endif ( usb_LIBRARY )
+
+endif ( PKGCONFIG_LIBUSB_FOUND )
+
+if ( LibUSB_INCLUDE_DIRS AND LibUSB_LIBRARIES )
+    set ( LibUSB_FOUND true )
+endif ( LibUSB_INCLUDE_DIRS AND LibUSB_LIBRARIES )
+
+if ( LibUSB_FOUND )
+    set ( CMAKE_REQUIRED_INCLUDES "${LibUSB_INCLUDE_DIRS}" )
+    check_include_file ( "${LibUSB_HEADER_FILE}" LibUSB_FOUND )
+endif ( LibUSB_FOUND )
+
+if ( LibUSB_FOUND )
+    check_library_exists ( "${LibUSB_LIBRARIES}" usb_open "" LibUSB_FOUND )
+    check_library_exists ( "${LibUSB_LIBRARIES}" libusb_get_device_list "" LibUSB_VERSION_1.0 )
+    check_library_exists ( "${LibUSB_LIBRARIES}" libusb_get_port_numbers "" LibUSB_VERSION_1.0.16 )
+
+    # Library 1.0.16+ compilation test.
+    # The check_library_exists does not work well on Apple with shared libs.
+    if (APPLE OR LibUSB_VERSION_1.0.16)
+        if (APPLE)
+            if(DEPENDS)
+                list(APPEND TEST_COMPILE_EXTRA_LIBRARIES "-framework Foundation -framework IOKit")
+            else()
+                find_library(COREFOUNDATION CoreFoundation)
+                find_library(IOKIT IOKit)
+                list(APPEND TEST_COMPILE_EXTRA_LIBRARIES ${IOKIT})
+                list(APPEND TEST_COMPILE_EXTRA_LIBRARIES ${COREFOUNDATION})
+            endif()
+        endif()
+        if (WIN32)
+            list(APPEND TEST_COMPILE_EXTRA_LIBRARIES setupapi)
+        endif()
+        list(APPEND TEST_COMPILE_EXTRA_LIBRARIES ${LibUSB_LIBRARIES})
+
+        try_compile(LibUSB_COMPILE_TEST_PASSED
+                ${CMAKE_BINARY_DIR}
+                "${CMAKE_SOURCE_DIR}/cmake/test-libusb-version.c"
+                CMAKE_FLAGS
+                    "-DINCLUDE_DIRECTORIES=${LibUSB_INCLUDE_DIRS}"
+                    "-DLINK_DIRECTORIES=${LibUSB_LIBRARIES}"
+                LINK_LIBRARIES ${TEST_COMPILE_EXTRA_LIBRARIES}
+                OUTPUT_VARIABLE OUTPUT)
+        unset(TEST_COMPILE_EXTRA_LIBRARIES)
+        message(STATUS "LibUSB Compilation test: ${LibUSB_COMPILE_TEST_PASSED}")
+    endif()
+endif ( LibUSB_FOUND )
+
+if ( NOT LibUSB_FOUND )
+    if ( NOT LibUSB_FIND_QUIETLY )
+        message ( STATUS "LibUSB not found, try setting LibUSB_ROOT_DIR environment variable." )
+    endif ( NOT LibUSB_FIND_QUIETLY )
+    if ( LibUSB_FIND_REQUIRED )
+        message ( FATAL_ERROR "" )
+    endif ( LibUSB_FIND_REQUIRED )
+endif ( NOT LibUSB_FOUND )

cmake/test-libusb-version.c

@@ -0,0 +1,52 @@
+// Copyright (c) 2014-2018, The Monero Project
+// 
+// All rights reserved.
+// 
+// Redistribution and use in source and binary forms, with or without modification, are
+// permitted provided that the following conditions are met:
+// 
+// 1. Redistributions of source code must retain the above copyright notice, this list of
+//    conditions and the following disclaimer.
+// 
+// 2. Redistributions in binary form must reproduce the above copyright notice, this list
+//    of conditions and the following disclaimer in the documentation and/or other
+//    materials provided with the distribution.
+// 
+// 3. Neither the name of the copyright holder nor the names of its contributors may be
+//    used to endorse or promote products derived from this software without specific
+//    prior written permission.
+// 
+// THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY
+// EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
+// MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL
+// THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+// SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+// PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
+// INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
+// STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF
+// THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+
+#include <libusb.h>
+
+#define UNUSED(expr) (void)(expr)
+
+int main(int argc, char *argv[]) {
+  libusb_device **devs;
+  libusb_context *ctx = NULL;
+
+  int r = libusb_init(&ctx); UNUSED(r);
+  ssize_t cnt = libusb_get_device_list(ctx, &devs); UNUSED(cnt);
+
+  struct libusb_device_descriptor desc;
+  r = libusb_get_device_descriptor(devs[0], &desc); UNUSED(r);
+  uint8_t bus_id = libusb_get_bus_number(devs[0]); UNUSED(bus_id);
+  uint8_t addr = libusb_get_device_address(devs[0]); UNUSED(addr);
+
+  uint8_t tmp_path[16];
+  r = libusb_get_port_numbers(devs[0], tmp_path, sizeof(tmp_path));
+  UNUSED(r);
+  UNUSED(tmp_path);
+
+  libusb_free_device_list(devs, 1);
+  libusb_exit(ctx);
+}