mirror of
https://gitgud.io/wackyideas/aerothemeplasma.git
synced 2026-06-19 03:45:50 +00:00
6f831d540f
This is a big update which requires existing users to migrate their desktop setup (Plasmoids, their configurations, layout changes, etc.) to a new desktop session. This commit replaces the modified desktop shell (org.kde.plasma.desktop) with ATP's shell (io.gitgud.wackyideas.desktop) which requires new session options. This is similar to how plasma-bigscreen and plasma-mobile are used - logging into a separate session via the login manager (SDDM). ATP will provide sessions for both X11 and Wayland. This, along with now providing a forked panel as well, is a step forward regarding separating ATP's codebase and KDE's upstream code. Further goals are to be able to further isolate the ATP session from the regular KDE session in terms of shared configurations, etc. For existing users - Rerun install_plasmoids.sh and install_plasma_components.sh, you can delete the old shell (shells/org.kde.plasma.desktop) and panel plasmoid (plasmoids/org.kde.panel). As mentioned previously, panel and desktop layouts, plasmoids and their configurations will not be migrated to the newly available sessions, so they need to be set up manually.
72 lines
2 KiB
QML
72 lines
2 KiB
QML
/*
|
|
SPDX-FileCopyrightText: 2017 Martin Gräßlin <mgraesslin@kde.org>
|
|
|
|
SPDX-License-Identifier: GPL-2.0-or-later
|
|
*/
|
|
|
|
import QtQuick 2.15
|
|
import QtQuick.VirtualKeyboard 2.4
|
|
|
|
import org.kde.plasma.core 2.0 as PlasmaCore
|
|
import org.kde.kirigami 2.20 as Kirigami
|
|
|
|
InputPanel {
|
|
id: inputPanel
|
|
property bool activated: false
|
|
active: activated && Qt.inputMethod.visible
|
|
width: parent.width
|
|
|
|
states: [
|
|
State {
|
|
name: "visible"
|
|
when: inputPanel.active
|
|
PropertyChanges {
|
|
target: inputPanel
|
|
y: inputPanel.parent.height - inputPanel.height
|
|
opacity: 1
|
|
visible: true
|
|
}
|
|
},
|
|
State {
|
|
name: "hidden"
|
|
when: !inputPanel.active
|
|
PropertyChanges {
|
|
target: inputPanel
|
|
y: inputPanel.parent.height
|
|
opacity: 0
|
|
visible:false
|
|
}
|
|
}
|
|
]
|
|
|
|
transitions: [
|
|
Transition {
|
|
to: "visible"
|
|
ParallelAnimation {
|
|
YAnimator {
|
|
// NOTE this is necessary as otherwise the keyboard always starts the transition with Y as 0, due to the internal reparenting happening when becomes active
|
|
from: inputPanel.parent.height
|
|
duration: Kirigami.Units.longDuration
|
|
easing.type: Easing.OutQuad
|
|
}
|
|
OpacityAnimator {
|
|
duration: Kirigami.Units.longDuration
|
|
easing.type: Easing.OutQuad
|
|
}
|
|
}
|
|
},
|
|
Transition {
|
|
to: "hidden"
|
|
ParallelAnimation {
|
|
YAnimator {
|
|
duration: Kirigami.Units.longDuration
|
|
easing.type: Easing.InQuad
|
|
}
|
|
OpacityAnimator {
|
|
duration: Kirigami.Units.longDuration
|
|
easing.type: Easing.InQuad
|
|
}
|
|
}
|
|
}
|
|
]
|
|
}
|