mirror of
https://gitgud.io/wackyideas/aerothemeplasma.git
synced 2026-06-19 03:45:50 +00:00
6f831d540f
This is a big update which requires existing users to migrate their desktop setup (Plasmoids, their configurations, layout changes, etc.) to a new desktop session. This commit replaces the modified desktop shell (org.kde.plasma.desktop) with ATP's shell (io.gitgud.wackyideas.desktop) which requires new session options. This is similar to how plasma-bigscreen and plasma-mobile are used - logging into a separate session via the login manager (SDDM). ATP will provide sessions for both X11 and Wayland. This, along with now providing a forked panel as well, is a step forward regarding separating ATP's codebase and KDE's upstream code. Further goals are to be able to further isolate the ATP session from the regular KDE session in terms of shared configurations, etc. For existing users - Rerun install_plasmoids.sh and install_plasma_components.sh, you can delete the old shell (shells/org.kde.plasma.desktop) and panel plasmoid (plasmoids/org.kde.panel). As mentioned previously, panel and desktop layouts, plasmoids and their configurations will not be migrated to the newly available sessions, so they need to be set up manually.
81 lines
2.5 KiB
QML
81 lines
2.5 KiB
QML
/*
|
|
SPDX-FileCopyrightText: 2020 Nicolas Fella <nicolas.fella@gmx.de>
|
|
|
|
SPDX-License-Identifier: GPL-2.0-or-later
|
|
*/
|
|
|
|
import QtQuick 2.0
|
|
import org.kde.plasma.plasmoid 2.0
|
|
import org.kde.kirigami 2.10 as Kirigami
|
|
|
|
Kirigami.ScrollablePage {
|
|
id: root
|
|
|
|
title: configItem.name
|
|
|
|
required property var configItem
|
|
|
|
signal settingValueChanged()
|
|
|
|
function saveConfig() {
|
|
const config = Plasmoid.configuration; // type: KConfigPropertyMap
|
|
|
|
config.keys().forEach(key => {
|
|
const cfgKey = "cfg_" + key;
|
|
if (cfgKey in loader.item) {
|
|
config[key] = loader.item[cfgKey];
|
|
}
|
|
})
|
|
|
|
Plasmoid.configuration.writeConfig();
|
|
|
|
// For ConfigurationContainmentActions.qml
|
|
if (loader.item.hasOwnProperty("saveConfig")) {
|
|
loader.item.saveConfig()
|
|
}
|
|
}
|
|
|
|
implicitHeight: loader.height
|
|
|
|
padding: configItem.includeMargins ? Kirigami.Units.largeSpacing : 0
|
|
bottomPadding: 0
|
|
|
|
Loader {
|
|
id: loader
|
|
width: parent.width
|
|
// HACK the height of the loader is based on the implicitHeight of the content.
|
|
// Unfortunately not all content items have a sensible implicitHeight.
|
|
// If it is zero fall back to the height of its children
|
|
// Also make it at least as high as the page itself. Some existing configs assume they fill the whole space
|
|
// TODO KF6 clean this up by making all configs based on SimpleKCM/ScrollViewKCM/GridViewKCM
|
|
height: Math.max(root.availableHeight, item.implicitHeight ? item.implicitHeight : item.childrenRect.height)
|
|
|
|
Component.onCompleted: {
|
|
const config = Plasmoid.configuration; // type: KConfigPropertyMap
|
|
|
|
const props = {};
|
|
|
|
config.keys().forEach(key => {
|
|
props["cfg_" + key] = config[key];
|
|
});
|
|
|
|
setSource(configItem.source, props);
|
|
}
|
|
|
|
onLoaded: {
|
|
const config = Plasmoid.configuration; // type: KConfigPropertyMap
|
|
|
|
config.keys().forEach(key => {
|
|
const changedSignal = item["cfg_" + key + "Changed"];
|
|
if (changedSignal) {
|
|
changedSignal.connect(() => root.settingValueChanged());
|
|
}
|
|
});
|
|
|
|
const configurationChangedSignal = item.configurationChanged;
|
|
if (configurationChangedSignal) {
|
|
configurationChangedSignal.connect(() => root.settingValueChanged());
|
|
}
|
|
}
|
|
}
|
|
}
|